DruidsRPGcvs.Summonifact

class Summonifact extends RPGArtifact
    abstract
    config(UT2004RPG);

var() Sound BrokenSound;
var class<Pawn> SummonItem;
var string FriendlyName;
var int Adrenaline;
var int Points;
var int StartHealth;

replication
{
    reliable if (Role == ROLE_Authority)
        Points, Adrenaline, FriendlyName;
}

static function bool ArtifactIsAllowed(GameInfo Game)
{
    return true;
}

function setup(String Name, class<Pawn> Item, int AdrenalineUsed, int PointsUsed, int InitialHealth)
{
    SummonItem = Item;
    Adrenaline = AdrenalineUsed;
    Points = PointsUsed;
    FriendlyName = Name;
    StartHealth = InitialHealth;
}

function BotConsider()
{
    if (bActive)
        return;

    if ( Instigator.Health + Instigator.ShieldStrength > 130 && Instigator.Controller.Enemy != None
         && Instigator.Controller.Adrenaline > rand(100) && NoArtifactsActive())
        Activate();
    return;     
}

function PostBeginPlay()
{
    Super.PostBeginPlay();

    disable('Tick'); //this artifact doesn't need ticks. It gets activated externally
}

// overridable functions for the different things that can be summoned
function bool SpawnIt(TransBeacon Beacon,Pawn P,EngineerPointsInv epi)
{
    return false;
}

function bool CanAirSummon()
{
    return false;
}

function bool isAvailable(LevelInfo level)
{
    return true;
}

function Activate()
{       
    local EngineerPointsInv Inv;
    Local TransLauncher tr;

    if (Instigator == None)
        return;
    Inv = EngineerPointsInv(Instigator.FindInventoryType(class'EngineerPointsInv'));
    if(Inv == None)
    {
        Inv = Instigator.spawn(class'EngineerPointsInv', Instigator,,, rot(0,0,0));
        if(Inv == None)
        {
            bActive = false;
            GotoState('');
            return; //get em next pass I guess?
        }

        Inv.giveTo(Instigator);
    }

    if (Instigator.Weapon == None || TransLauncher(Instigator.Weapon) == None)
    {
        Instigator.ReceiveLocalizedMessage(MessageClass, 2000, None, None, Class);
        bActive = false;
        GotoState('');
        return; //get em next pass I guess?
    }
    tr = TransLauncher(Instigator.Weapon);
    if (tr.TransBeacon == None)     // no beacon out, so can't spawn
    {
        Instigator.ReceiveLocalizedMessage(MessageClass, 3000, None, None, Class);
        bActive = false;
        GotoState('');
        return; //get em next pass I guess?
    }

    // let try to summon it. If it works, bring back the beacon.
    if (SpawnIt(tr.TransBeacon, Instigator, Inv))
    {
        // successfully summoned something
        tr.TransBeacon.Destroy();   
        tr.TransBeacon = None;
    }

}

function SetStartHealth(Vehicle NewItem)
{
    if (StartHealth > 0 && NewItem != None)
    {
        NewItem.Health = StartHealth;
        NewItem.HealthMax = StartHealth;
    }
    NewItem.SuperHealthMax = NewItem.HealthMax; // set to non-199 so can pickup later
}

function ApplyStatsToConstruction(Vehicle NewItem,Pawn Other)
{
    Local RPGStatsInv StatsInv;
    Local Inventory Inv;
    Local int x;


    if (NewItem == None)
        return;

    // and lets set the eject to be false. If you have the correct skill later, it can reset
    NewItem.bEjectDriver = False;

    for (Inv = Other.Controller.Inventory; Inv != None; Inv = Inv.Inventory)
    {
        StatsInv = RPGStatsInv(Inv);
        if (StatsInv != None)
            break;
    }
    if (StatsInv == None) //fallback, should never happen
        StatsInv = RPGStatsInv(Other.FindInventoryType(class'RPGStatsInv'));
    if (StatsInv != None)
    {
        for (x = 0; x < StatsInv.Data.Abilities.length; x++)
        {
            if(ClassIsChildOf(StatsInv.Data.Abilities[x], class'EngineerAbility'))
                class<EngineerAbility>(StatsInv.Data.Abilities[x]).static.ModifyConstruction(NewItem, StatsInv.Data.AbilityLevels[x]);
        }

        if (NewItem.Controller != None)
        {
            if (NewItem.Controller.Inventory == None)
                NewItem.Controller.Inventory = StatsInv;
            else
            {
                for (Inv = NewItem.Controller.Inventory; Inv.Inventory != None; Inv = Inv.Inventory)
                {}
                Inv.Inventory = StatsInv;
            }
        }
    }
}

static function string GetLocalString(optional int Switch, optional PlayerReplicationInfo RelatedPRI_1, optional PlayerReplicationInfo RelatedPRI_2)
{
    if (Switch == 2000)
        return "You need to be using the Translocator for this artifact to operate";
    if (Switch == 3000)
        return "You need to have the Translocator beacon deployed to use this artifact";
    if (Switch == 4000)
        return "There is nothing to spawn the item on";
    return default.Adrenaline@"Adrenaline and"@default.Points@"points are required to use this artifact";
}

defaultproperties
{
    MinActivationTime=0.000001
    CostPerSec=1
    BrokenSound=Sound'PlayerSounds.NewGibs.RobotCrunch3'
    ItemName="Summoning Artifact"
    IconMaterial=Texture'UTRPGTextures.Icons.SummoningCharmIcon'
}