DruidsRPGcvs.DamageInv

class DamageInv extends Inventory;

var RPGRules Rules;
var int ExpPerSecond;
var vector CoreLocation;
var Controller DamagePlayerController;
var float EffectRadius;
var Material EffectOverlay;

replication
{
    reliable if (bNetInitial && Role == ROLE_Authority)
        DamagePlayerController,CoreLocation;
}

simulated function PostBeginPlay()
{
    Super.PostBeginPlay();

    SetTimer(1, true);
}

function SwitchOffDamage()
{
    // need to switch off invulnerability if we are the only source for this player
    // no other sphere will have started while we were running
    // if he started the globe, tough luck

    Pawn(Owner).DisableUDamage();
    if (PlayerController(Pawn(Owner).Controller) != None)
    {
        PlayerController(Pawn(Owner).Controller).ReceiveLocalizedMessage(class'DamageConditionMessage', 1);
    }
    Pawn(Owner).SetOverlayMaterial(EffectOverlay, -1, true);
}

simulated function Timer()
{
    local ArtifactSphereDamage InitiatingSphere;
    if (Role == ROLE_Authority)
    {

        if ((Owner == None) || (DamagePlayerController == None) || (Pawn(Owner) == None) || (Pawn(Owner).Controller == None))
        {   // got problems.
            Destroy();
            return;
        }

        if (!Pawn(Owner).HasUDamage())
        {   // if the owner hasn't got udamage anymore, then not active, so destroy
            Destroy();
            return;
        }

        if ((DamagePlayerController.Pawn == None) || (DamagePlayerController.Pawn.Health <= 0) || !DamagePlayerController.Pawn.HasUDamage() )
        {   // initiating player hasn't got udamage anymore, so artifact must have stopped
            SwitchOffDamage();
            Destroy();
            return;
        }

        // lets find the artifact
        InitiatingSphere = ArtifactSphereDamage(DamagePlayerController.Pawn.FindInventoryType(class'ArtifactSphereDamage'));

        // ok, lets check if still in range and artifact still active
        if ((VSize(Pawn(Owner).Location - CoreLocation) > EffectRadius) || (InitiatingSphere == None) || (!InitiatingSphere.bActive))
        {   // now out of range
            SwitchOffDamage();
            Destroy();
            return;
        }

        // ok, lets see if the initiator gets any xp
        if ((ExpPerSecond > 0) && (Rules != None))
        {
            Rules.ShareExperience(RPGStatsInv(DamagePlayerController.Pawn.FindInventoryType(class'RPGStatsInv')), ExpPerSecond);
        }
    }

    //dont call super. Bad things will happen.
}

defaultproperties
{
     EffectOverlay=Shader'XGameShaders.PlayerShaders.WeaponUDamageShader'
     bOnlyRelevantToOwner=False
}