DruidsRPGcvs.RW_EnhancedInfinity

class RW_EnhancedInfinity extends OneDropRPGWeapon
    HideDropDown
    CacheExempt
    config(UT2004RPG);

var config float DamageBonus;

static function bool AllowedFor(class<Weapon> Weapon, Pawn Other)
{
    if ( Weapon.default.FireModeClass[0] != None && Weapon.default.FireModeClass[0].default.AmmoClass != None
              && class'MutUT2004RPG'.static.IsSuperWeaponAmmo(Weapon.default.FireModeClass[0].default.AmmoClass) )
        return false;

    return true;
}

simulated function bool StartFire(int Mode)
{
    if (!bIdentified && Role == ROLE_Authority)
        Identify();

    return Super.StartFire(Mode);
}

function bool ConsumeAmmo(int Mode, float Load, bool bAmountNeededIsMax)
{
    if (!bIdentified)
        Identify();

    return true;
}

simulated function WeaponTick(float dt)
{
    MaxOutAmmo();

    Super.WeaponTick(dt);
}

function AdjustTargetDamage(out int Damage, Actor Victim, Vector HitLocation, out Vector Momentum, class<DamageType> DamageType)
{
    if (!bIdentified)
        Identify();

    if (!class'OneDropRPGWeapon'.static.CheckCorrectDamage(ModifiedWeapon, DamageType))
        return;

    if(damage > 0)
    {
        Damage = Max(1, Damage * (1.0 + DamageBonus * Modifier));
        Momentum *= 1.0 +DamageBonus * Modifier;
    }
}

defaultproperties
{
    DamageBonus=0.050000
    AIRatingBonus=0.050000
    PostfixPos=" of Infinity"
    PostfixNeg=" of Infinity"
    bCanHaveZeroModifier=True
    MaxModifier=4
    MinModifier=-2
    ModifierOverlay=Shader'XGameShaders.BRShaders.BombIconRS'
}