DruidsRPGcvs.EngineerInteraction

class EngineerInteraction extends Interaction
    config(UT2004RPG);

var EngineerPointsInv EInv;
var Font TextFont;
var color EPBarColor, WhiteColor, RedTeamTint, BlueTeamTint;
var localized string EPText, AdrenalineText, PointsText;
var int dummyi;

event Initialized()
{
    TextFont = Font(DynamicLoadObject("UT2003Fonts.jFontSmall", class'Font'));
    super.Initialized();
}

//Find local player's stats inventory item
function FindEPInv()
{
    local Inventory Inv;
    local EngineerPointsInv FoundEInv;

    for (Inv = ViewportOwner.Actor.Inventory; Inv != None; Inv = Inv.Inventory)
    {
        FoundEInv = EngineerPointsInv(Inv);
        if (FoundEInv != None)
        {
            if (FoundEInv.Owner == ViewportOwner.Actor || FoundEInv.Owner == ViewportOwner.Actor.Pawn)
                EInv = FoundEInv;
            return;
        }
        else
        {
            //atrocious hack for Jailbreak's bad code in JBTag (sets its Inventory property to itself)
            if (Inv.Inventory == Inv)
            {
                Inv.Inventory = None;
                foreach ViewportOwner.Actor.DynamicActors(class'EngineerPointsInv', FoundEInv)
                {
                    if (FoundEInv.Owner == ViewportOwner.Actor || FoundEInv.Owner == ViewportOwner.Actor.Pawn)
                    {
                        EInv = FoundEInv;
                        Inv.Inventory = EInv;
                        break;
                    }
                }
                return;
            }
        }
    }
}

function PostRender(Canvas Canvas)
{
    local float XL, YL, XLSmall, YLSmall, EPBarX, EPBarY;
    local Summonifact Sf;
    local int UsedPoints, TotalPoints;
    local string pText;

    if ( ViewportOwner == None || ViewportOwner.Actor == None || ViewportOwner.Actor.Pawn == None || ViewportOwner.Actor.Pawn.Health <= 0
         || (ViewportOwner.Actor.myHud != None && ViewportOwner.Actor.myHud.bShowScoreBoard)
         || ViewportOwner.Actor.myHud.bHideHUD )
        return;

    if (EInv == None)
        FindEPInv();
    if (EInv == None)
        return;
    UsedPoints = EInv.UsedTurretPoints+EInv.UsedVehiclePoints+EInv.UsedBuildingPoints;
    TotalPoints = EInv.TotalTurretPoints+EInv.TotalVehiclePoints+EInv.TotalBuildingPoints;
// Spectators shouldn't get the Total/UsedXObjPoints replicated now, so
// this should detect them appropriately.  Ideally, EInv won't be found
// either, but I don't know if I trust that - so this for sure will
// result in former spectators not seeing the display on spawn.
    if(TotalPoints == 0)
        return;

    if (TextFont != None)
        Canvas.Font = TextFont;
    Canvas.FontScaleX = Canvas.ClipX / 1024.f;
    Canvas.FontScaleY = Canvas.ClipY / 768.f;

    Canvas.FontScaleX *= 0.75; //make it smaller
    Canvas.FontScaleY *= 0.75;

    Canvas.TextSize(EPText, XL, YL);

    // increase size of the display if necessary for really high levels
    XL = FMax(XL + 9.f * Canvas.FontScaleX, 135.f * Canvas.FontScaleX);

    Canvas.Style = 5;
    Canvas.DrawColor = EPBarColor;
    EPBarX = Canvas.ClipX - XL - 1.f;
    EPBarY = Canvas.ClipY * 0.75 - YL * 2.5; //used to be 1.75. 
    Canvas.SetPos(EPBarX, EPBarY);
    if (EInv.TotalBuildingPoints > 0)
        Canvas.DrawTile(Material'InterfaceContent.Hud.SkinA', XL * EInv.UsedBuildingPoints / EInv.TotalBuildingPoints, 5.0 * Canvas.FontScaleY * 1.25, 836, 454, -386 * EInv.UsedBuildingPoints / EInv.TotalBuildingPoints, 36);
    Canvas.SetPos(EPBarX, EPBarY+(5* Canvas.FontScaleY * 1.25));
    if (EInv.TotalTurretPoints > 0)
        Canvas.DrawTile(Material'InterfaceContent.Hud.SkinA', XL * EInv.UsedTurretPoints / EInv.TotalTurretPoints, 5.0 * Canvas.FontScaleY * 1.25, 836, 454, -386 * EInv.UsedTurretPoints / EInv.TotalTurretPoints, 36);
    Canvas.SetPos(EPBarX, EPBarY+(10  * Canvas.FontScaleY * 1.25));
    if (EInv.TotalVehiclePoints > 0)
        Canvas.DrawTile(Material'InterfaceContent.Hud.SkinA', XL * EInv.UsedVehiclePoints / EInv.TotalVehiclePoints, 5.0 * Canvas.FontScaleY * 1.25, 836, 454, -386 * EInv.UsedVehiclePoints / EInv.TotalVehiclePoints, 36);
    if ( ViewportOwner.Actor.PlayerReplicationInfo == None || ViewportOwner.Actor.PlayerReplicationInfo.Team == None
         || ViewportOwner.Actor.PlayerReplicationInfo.Team.TeamIndex != 0 )
        Canvas.DrawColor = BlueTeamTint;
    else
        Canvas.DrawColor = RedTeamTint;
    Canvas.SetPos(EPBarX, EPBarY);
    Canvas.DrawTile(Material'InterfaceContent.Hud.SkinA', XL, 15.0 * Canvas.FontScaleY * 1.25, 836, 454, -386, 36);
    Canvas.DrawColor = WhiteColor;
    Canvas.SetPos(EPBarX, EPBarY);
    Canvas.DrawTile(Material'InterfaceContent.Hud.SkinA', XL, 16.0 * Canvas.FontScaleY * 1.25, 836, 415, -386, 38);

    Canvas.Style = 2;
    Canvas.DrawColor = WhiteColor;

    Canvas.SetPos(EPBarX + 9.f * Canvas.FontScaleX, Canvas.ClipY * 0.75 - YL * 3.7); //used to be 3
    Canvas.DrawText(EPText);

    pText = EInv.UsedBuildingPoints$":"$EInv.UsedTurretPoints$":"$EInv.UsedVehiclePoints$"/"$EInv.TotalBuildingPoints$":"$EInv.TotalTurretPoints$":"$EInv.TotalVehiclePoints;
    Canvas.TextSize(pText, XLSmall, YLSmall);
    Canvas.SetPos(Canvas.ClipX - XL * 0.5 - XLSmall * 0.5, Canvas.ClipY * 0.75 - YL * 2.5 + 12.5 * Canvas.FontScaleY - YLSmall * 0.5); //used to be 3.75
    Canvas.DrawText(pText);

    Sf = Summonifact(ViewportOwner.Actor.Pawn.SelectedItem);
    if (Sf != None)
    {
        //Draw summoning item "Artifact" HUD info

        Canvas.FontScaleX = Canvas.default.FontScaleX * 0.80;
        Canvas.FontScaleY = Canvas.default.FontScaleY * 0.80;

        Canvas.SetPos(10, Canvas.ClipY * 0.75 - YL * 7.65);
        Canvas.DrawText(Sf.FriendlyName);
        Canvas.SetPos(10, Canvas.ClipY * 0.75 - YL * 6.75);
        Canvas.DrawText(AdrenalineText $ Sf.Adrenaline);
        Canvas.SetPos(10, Canvas.ClipY * 0.75 - YL * 5.85);
        Canvas.DrawText(PointsText $ Sf.Points);
    }

    Canvas.FontScaleX = Canvas.default.FontScaleX;
    Canvas.FontScaleY = Canvas.default.FontScaleY;
    super.PostRender(Canvas);
}

event NotifyLevelChange()
{
    //close stats menu if it's open
    Master.RemoveInteraction(self);
    EInv.Interaction = None;
    super.NotifyLevelChange();
}

defaultproperties
{
     EPBarColor=(B=128,G=255,R=128,A=255)
     WhiteColor=(B=255,G=255,R=255,A=255)
     RedTeamTint=(R=100,A=100)
     BlueTeamTint=(B=102,G=66,R=37,A=150)
     EPText="Engineer Points:"
     AdrenalineText="Adrenaline:"
     PointsText="Points:"
     bVisible=True
}