DruidsRPGcvs.DruidArtifactLoaded

class DruidArtifactLoaded extends RPGDeathAbility
    config(UT2004RPG) 
    abstract;

var config Array< class<RPGArtifact> > SlowArtifact;
var config Array< class<RPGArtifact> > QuickArtifact;

static simulated function int Cost(RPGPlayerDataObject Data, int CurrentLevel)
{
    local int x;
    local bool ok;

    for (x = 0; x < Data.Abilities.length && !ok; x++)
        if (Data.Abilities[x] == class'ClassAdrenalineMaster')
            ok = true;
    if(!ok)
    {
        if(CurrentLevel > 0)
            log("Warning:"@data.Name@"has"@default.class@"Level"@CurrentLevel@"but does not have an associated Class to allow them to purchase it");
        return 0;
    }

    return Super.Cost(Data, CurrentLevel);
}

static function ModifyPawn(Pawn Other, int AbilityLevel)
{
    local int x;
    local LoadedInv LoadedInv;

    LoadedInv = LoadedInv(Other.FindInventoryType(class'LoadedInv'));

    if(LoadedInv != None)
    {
        if(LoadedInv.type != 'Artifacts' || LoadedInv.AbilityLevel != AbilityLevel)
            LoadedInv.Destroy(); //for when they buy a new level of this skill
        else
            return;
    }

    LoadedInv = Other.spawn(class'LoadedInv');

    if(LoadedInv == None)
        return;

    LoadedInv.type = 'Artifacts';
    LoadedInv.AbilityLevel = AbilityLevel;

    if(AbilityLevel >= 3)
        LoadedInv.ProtectArtifacts = true;
    else
        LoadedInv.ProtectArtifacts = false;

    for(x = 0; x < default.SlowArtifact.length; x++)
        giveArtifact(other, default.SlowArtifact[x]);

    if(AbilityLevel > 1)
        for(x = 0; x < default.QuickArtifact.length; x++)
            giveArtifact(other, default.QuickArtifact[x]);

// I'm guessing that NextItem is here to ensure players don't start with
// no item selected.  So the if should stop wierd artifact scrambles.
    if(Other.SelectedItem == None)
        Other.NextItem();

    LoadedInv.giveTo(Other);
}

static function giveArtifact(Pawn other, class<RPGArtifact> ArtifactClass)
{
    local RPGArtifact Artifact;

    if(Other.IsA('Monster'))
        return;
    if(Other.findInventoryType(ArtifactClass) != None)
        return; //they already have one
        
    Artifact = Other.spawn(ArtifactClass, Other,,, rot(0,0,0));
    if(Artifact != None)
        Artifact.giveTo(Other);
}

static function GenuineDeath(Pawn Killed, Controller Killer, class<DamageType> DamageType, vector HitLocation, int AbilityLevel)
{
    Local Inventory inv;

// If we end up with some wierdness here, it would be because we haven't
// ejected the player.  However, we shouldn't have to worry about that
// any more; it should be handled elsewhere, if needed.
    if(Killed.isA('Vehicle'))
    {
        Killed = Vehicle(Killed).Driver;
    }
// Wierdness - looks like sometimes PD called twice, particularly in VINV?
// Killed can become "None" somewhere along the line.
    if(Killed == None)
    {
        return;
    }

    for (inv=Killed.Inventory ; inv != None ; inv=inv.Inventory)
    {
        if(ClassIsChildOf(inv.class, class'UT2004RPG.RPGArtifact'))
        {
// Important note: *NO* artifact currently in possession will get dropped!
            inv.PickupClass = None;
        }
    }

    return;
}


DefaultProperties
{
    AbilityName="Loaded Artifacts"
    Description="When you spawn:|Level 1: You are granted all slow drain artifacts and a magic weapon maker.|Level 2: You are granted all fast drain artifacts and some special artifacts.|Level 3: Your breakable artifacts are made unbreakable. You must be an Adrenaline Master to purchase this skill.|Cost (per level): 2,9,16"
    
    StartingCost=2
    CostAddPerLevel=7
    MaxLevel=3
          
    SlowArtifact[0]=class'UT2004RPG.ArtifactFlight'
    SlowArtifact[1]=class'UT2004RPG.ArtifactTeleport'
    SlowArtifact[2]=class'DruidArtifactSpider'
    SlowArtifact[3]=class'DruidArtifactMakeMagicWeapon'
    
    QuickArtifact[0]=class'DruidDoubleModifier'
    QuickArtifact[1]=class'DruidMaxModifier'
    QuickArtifact[2]=class'DruidPlusOneModifier'
    QuickArtifact[3]=class'UT2004RPG.ArtifactInvulnerability'
    QuickArtifact[4]=class'DruidArtifactTripleDamage'
    QuickArtifact[5]=class'DruidArtifactLightningRod'
}