DruidsRPGcvs.AbilityTurretPoints

class AbilityTurretPoints extends RPGAbility
    config(UT2004RPG)
    abstract;

static simulated function int Cost(RPGPlayerDataObject Data, int CurrentLevel)
{
    local bool ok;
    local int x;

    for (x = 0; x < Data.Abilities.length; x++)
        if (Data.Abilities[x] == class'ClassEngineer')
            ok = true;
    if(!ok)
    {
        if(CurrentLevel > 0)
            log("Warning:"@data.Name@"has"@default.class@"Level"@CurrentLevel@"but does not have an associated Class to allow them to purchase it");
        return 0;
    }

    return super.Cost(Data, CurrentLevel);
}

static function ModifyPawn(Pawn Other, int AbilityLevel)
{
    local EngineerPointsInv Inv;

    if(Monster(Other) != None)
        return; //Not for pets

    Inv = EngineerPointsInv(Other.FindInventoryType(class'EngineerPointsInv'));

    if(Inv != None)
    {
        if(Inv.TotalTurretPoints == AbilityLevel)
            return;
    }
    else
    {
        Inv = Other.spawn(class'EngineerPointsInv', Other,,, rot(0,0,0));
        if(Inv == None)
            return; //get em next pass I guess?

        Inv.giveTo(Other);
    }
    Inv.TotalTurretPoints = AbilityLevel;
}

defaultproperties
{
     AbilityName="Turret Points"
     Description="Allows you to summon turrets with the loaded engineer skill. (Max Level: 20)|You must be an Engineer to purchase this skill.|Cost (per level): 2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21"
     StartingCost=2
     CostAddPerLevel=1
     MaxLevel=20
}