UT2004 UnrealScript - Source: XEffects.Gib

00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101

class Gib extends Actor
    abstract;

var class<xPawnGibGroup> GibGroupClass;
var() class<xEmitter> TrailClass;
var() xEmitter Trail;
var() float DampenFactor;
var Sound   HitSounds[2];
var bool bFlaming;

simulated function Destroyed()
{
    if( Trail != None )
        Trail.mRegen = false;

    Super.Destroyed();
}

simulated final function RandSpin(float spinRate)
{
    DesiredRotation = RotRand();
    RotationRate.Yaw = spinRate * 2 *FRand() - spinRate;
    RotationRate.Pitch = spinRate * 2 *FRand() - spinRate;
    RotationRate.Roll = spinRate * 2 *FRand() - spinRate;   
}

simulated function Landed( Vector HitNormal )
{
    HitWall( HitNormal, None );
}
  
simulated function HitWall( Vector HitNormal, Actor Wall )
{
    local float Speed, MinSpeed;

    Velocity = DampenFactor * ((Velocity dot HitNormal) * HitNormal*(-2.0) + Velocity);
    RandSpin(100000);
    Speed = VSize(Velocity);
    if (  Level.DetailMode == DM_Low )
        MinSpeed = 250;
    else
        MinSpeed = 150;
    if( !bFlaming && (Speed > MinSpeed) )
    {
        if( (Level.NetMode != NM_DedicatedServer) && !Level.bDropDetail )
        {
            if ( GibGroupClass.default.BloodHitClass != None )
                Spawn( GibGroupClass.default.BloodHitClass,,, Location, Rotator(-HitNormal) );
            if ( (LifeSpan < 7.3)  && (Level.DetailMode != DM_Low) )
                PlaySound(HitSounds[Rand(2)]);
        }
    }

    if( Speed < 20 ) 
    {
        if( !bFlaming && !Level.bDropDetail && (Level.DetailMode != DM_Low) && GibGroupClass.default.BloodHitClass != None )
            Spawn( GibGroupClass.default.BloodHitClass,,, Location, Rotator(-HitNormal) );
        bBounce = False;
        SetPhysics(PHYS_None);
    }
}

simulated function SpawnTrail()
{
    if ( Level.NetMode != NM_DedicatedServer )
    {
        if ( bFlaming )
        {
            Trail = Spawn(class'HitFlameBig', self,,Location,Rotation);
            Trail.LifeSpan = 4 + 2*FRand();
            LifeSpan = Trail.LifeSpan;
            Trail.SetTimer(LifeSpan - 3.0,false);
        }
        else
        {
            Trail = Spawn(TrailClass, self,, Location, Rotation);
            Trail.LifeSpan = 1.8;
        }
        Trail.SetPhysics( PHYS_Trailer );
        RandSpin( 64000 );
    }
}

defaultproperties
{
     GibGroupClass=Class'XEffects.xPawnGibGroup'
     DampenFactor=0.650000
     HitSounds(0)=Sound'PlayerSounds.Final.Giblets1'
     HitSounds(1)=Sound'PlayerSounds.Final.Giblets2'
     Physics=PHYS_Falling
     RemoteRole=ROLE_None
     LifeSpan=8.000000
     bUnlit=True
     TransientSoundVolume=0.170000
     bCollideWorld=True
     bUseCylinderCollision=True
     bBounce=True
     bFixedRotationDir=True
     Mass=30.000000
}