DruidsRPGcvs.EngineerPointsInv

class EngineerPointsInv extends Inventory
    config(UT2004RPG);

//this class is the summoning nexus for all things that can be summoned by Engineers in DruidsRPG

var array<Pawn> SummonedTurrets;
var array<int> SummonedTurretPoints;
var int TotalTurretPoints;
var int UsedTurretPoints;

var array<Pawn> SummonedVehicles;
var array<int> SummonedVehiclePoints;
var int TotalVehiclePoints;
var int UsedVehiclePoints;

var array<Pawn> SummonedBuildings;
var array<int> SummonedBuildingPoints;
var int TotalBuildingPoints;
var int UsedBuildingPoints;

var config int MaxTurrets, MaxVehicles, MaxBuildings;

var localized string NotEnoughAdrenalineMessage;
var localized string NotEnoughPointsMessage;
var localized string UnableToSpawnMessage;
var localized string TooManyToSpawnMessage;

//client side only
var PlayerController PC;
var Player Player;
var EngineerInteraction Interaction;

replication
{
    reliable if (bNetOwner && bNetDirty && Role == ROLE_Authority)
        TotalTurretPoints, UsedTurretPoints, TotalVehiclePoints, UsedVehiclePoints, TotalBuildingPoints, UsedBuildingPoints;
    reliable if (bNetOwner && Role == ROLE_Authority)
        RemoveInteraction;
}

function PostBeginPlay()
{
    if(Level.NetMode == NM_DedicatedServer || Level.NetMode == NM_ListenServer || Level.NetMode == NM_Standalone)
        setTimer(5, true);
    super.postBeginPlay();

    if (!Level.Game.bAllowVehicles)
        Level.Game.bAllowVehicles = true;

}

simulated function PostNetBeginPlay()
{
    if(Level.NetMode != NM_DedicatedServer)
        enable('Tick');
    super.PostNetBeginPlay();
}

simulated function Tick(float deltaTime)
{
    local int x;
    if (Level.NetMode == NM_DedicatedServer || Interaction != None)
    {
        disable('Tick');
    }
    else
    {
        PC = Level.GetLocalPlayerController();
        if (PC != None)
        {
            Player = PC.Player;
            if(Player != None)
            {
                //first, find out if they have the interaction already.
                
                for(x = 0; x < Player.LocalInteractions.length; x++)
                {
                    if(EngineerInteraction(Player.LocalInteractions[x]) != None)
                    {
                        Interaction = EngineerInteraction(Player.LocalInteractions[x]);
                        Interaction.EInv = self;
                    }
                }
                if(Interaction == None) //they dont have one
                    AddInteraction();
            }
            if(Interaction != None)
                disable('Tick');
        }
    }
}


//not done through the interaction master, because that requires a string with a package name.
simulated function AddInteraction()
{
    Interaction = new class'EngineerInteraction';

    if (Interaction != None)
    {
        Player.LocalInteractions.Length = Player.LocalInteractions.Length + 1;
        Player.LocalInteractions[Player.LocalInteractions.Length-1] = Interaction;
        Interaction.ViewportOwner = Player;

        // Initialize the Interaction

        Interaction.Initialize();
        Interaction.Master = Player.InteractionMaster;
        Interaction.EInv = self;
    }
    else
        Log("Could not create EngineerInteraction");

} // AddInteraction

function Vector GetSpawnHeight(Vector BeaconLocation)
{
    // hack to ensure turrets aren't spawned too high in the air.
    local Vector DownEndLocation;
    local vector HitLocation;
    local vector HitNormal;
    local Actor AHit;
    
    DownEndLocation = BeaconLocation + vect(0,0,-30000);

    // See if we hit something.
        AHit = Trace(HitLocation, HitNormal, DownEndLocation, BeaconLocation, true);
    if (AHit == None)
        return vect(0,0,0);     // invalid, nothing to spawn on
    else 
        return HitLocation;
}

function ASVehicle_Sentinel SummonSentinel(class<Pawn> ChosenTurret, int Adrenaline, int TurretPoints, Pawn P, Vector SpawnLocation)
{
    Local ASVehicle_Sentinel T;
    local rotator SpawnRotation;

    if(TotalTurretPoints - UsedTurretPoints < TurretPoints)
    {
        P.ReceiveLocalizedMessage(MessageClass, 2, None, None, Class);
        return None;
    }

    if(SummonedTurrets.length >= MaxTurrets)
    {
        P.ReceiveLocalizedMessage(MessageClass, 4, None, None, Class);
        return None;
    }

    if (P.Controller.Adrenaline < Adrenaline)
    {
        P.ReceiveLocalizedMessage(MessageClass, 1, None, None, Class);
        return None;
    }

    SpawnRotation = getSpawnRotator(SpawnLocation);
    SpawnLocation.z += 55;      // lift just off ground

    T = ASVehicle_Sentinel(spawn(ChosenTurret,,, SpawnLocation, SpawnRotation));
    if(T == None)
    {
        P.ReceiveLocalizedMessage(MessageClass, 3, None, None, Class);
        return None;
    }

    if (T.Controller != None)
        T.Controller.Destroy();
    T.bAutoTurret=true;
    T.bNonHumanControl=true;

    P.Controller.Adrenaline -= Adrenaline;

    UsedTurretPoints += TurretPoints;
    SummonedTurrets[SummonedTurrets.length] = T;
    SummonedTurretPoints[SummonedTurretPoints.length] = TurretPoints;

    return T;
}

function ASTurret_LinkTurret SummonLinkSentinel(class<Pawn> ChosenTurret, int Adrenaline, int TurretPoints, Pawn P, Vector SpawnLocation)
{
    Local ASTurret_LinkTurret T;
    local rotator SpawnRotation;

    if(TotalTurretPoints - UsedTurretPoints < TurretPoints)
    {
        P.ReceiveLocalizedMessage(MessageClass, 2, None, None, Class);
        return None;
    }

    if(SummonedTurrets.length >= MaxTurrets)
    {
        P.ReceiveLocalizedMessage(MessageClass, 4, None, None, Class);
        return None;
    }

    if (P.Controller.Adrenaline < Adrenaline)
    {
        P.ReceiveLocalizedMessage(MessageClass, 1, None, None, Class);
        return None;
    }

    SpawnRotation = getSpawnRotator(SpawnLocation);
    SpawnLocation.z += 70;      // lift just off ground

    T = ASTurret_LinkTurret(spawn(ChosenTurret,,, SpawnLocation, SpawnRotation));
    if(T == None)
    {
        P.ReceiveLocalizedMessage(MessageClass, 3, None, None, Class);
        return None;
    }

    if (T.Controller != None)
        T.Controller.Destroy();
    T.bAutoTurret=true;
    T.bNonHumanControl=true;

    P.Controller.Adrenaline -= Adrenaline;

    UsedTurretPoints += TurretPoints;
    SummonedTurrets[SummonedTurrets.length] = T;
    SummonedTurretPoints[SummonedTurretPoints.length] = TurretPoints;

    return T;
}

function ASTurret SummonBaseSentinel(class<Pawn> ChosenTurret, int Adrenaline, int TurretPoints, Pawn P, Vector SpawnLocation)
{
    Local ASTurret T;
    local rotator SpawnRotation;

    if(TotalTurretPoints - UsedTurretPoints < TurretPoints)
    {
        P.ReceiveLocalizedMessage(MessageClass, 2, None, None, Class);
        return None;
    }

    if(SummonedTurrets.length >= MaxTurrets)
    {
        P.ReceiveLocalizedMessage(MessageClass, 4, None, None, Class);
        return None;
    }

    if (P.Controller.Adrenaline < Adrenaline)
    {
        P.ReceiveLocalizedMessage(MessageClass, 1, None, None, Class);
        return None;
    }

    SpawnRotation = getSpawnRotator(SpawnLocation);
    SpawnLocation.z += 80;      // lift just off ground

    T = ASTurret(spawn(ChosenTurret,,, SpawnLocation, SpawnRotation));
    if(T == None)
    {
        P.ReceiveLocalizedMessage(MessageClass, 3, None, None, Class);
        return None;
    }

    if (T.Controller != None)
        T.Controller.Destroy();
    T.bAutoTurret=true;
    T.bNonHumanControl=true;

    P.Controller.Adrenaline -= Adrenaline;

    UsedTurretPoints += TurretPoints;
    SummonedTurrets[SummonedTurrets.length] = T;
    SummonedTurretPoints[SummonedTurretPoints.length] = TurretPoints;

    return T;
}

function ASTurret SummonTurret(class<Pawn> ChosenTurret, int Adrenaline, int TurretPoints, Pawn P, Vector SpawnLocation)
{
    Local ASTurret T;
    local rotator SpawnRotation;

    if(TotalTurretPoints - UsedTurretPoints < TurretPoints)
    {
        P.ReceiveLocalizedMessage(MessageClass, 2, None, None, Class);
        return None;
    }

    if(SummonedTurrets.length >= MaxTurrets)
    {
        P.ReceiveLocalizedMessage(MessageClass, 4, None, None, Class);
        return None;
    }
    if (P.Controller.Adrenaline < Adrenaline)
    {
        P.ReceiveLocalizedMessage(MessageClass, 1, None, None, Class);
        return None;
    }

    SpawnRotation = getSpawnRotator(SpawnLocation);
    SpawnLocation.z += 55;      // lift just off ground

    T = ASTurret(spawn(ChosenTurret,,, SpawnLocation, SpawnRotation));
    if(T == None)
    {
        P.ReceiveLocalizedMessage(MessageClass, 3, None, None, Class);
        return None;
    }

    if (T.Controller != None)
        T.Controller.Destroy();

    P.Controller.Adrenaline -= Adrenaline;

    UsedTurretPoints += TurretPoints;
    SummonedTurrets[SummonedTurrets.length] = T;
    SummonedTurretPoints[SummonedTurretPoints.length] = TurretPoints;

    return T;
}

function Vehicle SummonVehicle(class<Pawn> ChosenVehicle, int Adrenaline, int VehiclePoints, Pawn P, Vector SpawnLocation)
{
    Local Vehicle V;
    local rotator SpawnRotation;

    if(TotalVehiclePoints - UsedVehiclePoints < VehiclePoints)
    {
        P.ReceiveLocalizedMessage(MessageClass, 2, None, None, Class);
        return None;
    }

    if(SummonedVehicles.length >= MaxVehicles)
    {
        P.ReceiveLocalizedMessage(MessageClass, 4, None, None, Class);
        return None;
    }

    if (P.Controller.Adrenaline < Adrenaline)
    {
        P.ReceiveLocalizedMessage(MessageClass, 1, None, None, Class);
        return None;
    }

    SpawnRotation = getSpawnRotator(SpawnLocation);
    SpawnLocation.z += 55;      // lift just off ground

    V = Vehicle(spawn(ChosenVehicle,,, SpawnLocation, SpawnRotation));
    if(V == None)
    {
        P.ReceiveLocalizedMessage(MessageClass, 3, None, None, Class);
        return None;
    }

    if (V.Controller != None)
        V.Controller.Destroy();

    P.Controller.Adrenaline -= Adrenaline;

    UsedVehiclePoints += VehiclePoints;
    SummonedVehicles[SummonedVehicles.length] = V;
    SummonedVehiclePoints[SummonedVehiclePoints.length] = VehiclePoints;

    return V;
}

function Vehicle SummonBuilding(class<Pawn> ChosenBuilding, int Adrenaline, int BuildingPoints, Pawn P, Vector SpawnLocation)
{
    Local Vehicle B;
    local rotator SpawnRotation;

    if(TotalBuildingPoints - UsedBuildingPoints < BuildingPoints)
    {
        P.ReceiveLocalizedMessage(MessageClass, 2, None, None, Class);
        return None;
    }

    if(SummonedBuildings.length >= MaxBuildings)
    {
        P.ReceiveLocalizedMessage(MessageClass, 4, None, None, Class);
        return None;
    }
    if (P.Controller.Adrenaline < Adrenaline)
    {
        P.ReceiveLocalizedMessage(MessageClass, 1, None, None, Class);
        return None;
    }

    SpawnRotation = getSpawnRotator(SpawnLocation);
    SpawnLocation.z += 55;      // lift just off ground

    B = Vehicle(spawn(ChosenBuilding,,, SpawnLocation, SpawnRotation));
    if(B == None)
    {
        P.ReceiveLocalizedMessage(MessageClass, 3, None, None, Class);
        return None;
    }

    if (B.Controller != None)
        B.Controller.Destroy();

    P.Controller.Adrenaline -= Adrenaline;

    UsedBuildingPoints += BuildingPoints;
    SummonedBuildings[SummonedBuildings.length] = B;
    SummonedBuildingPoints[SummonedBuildingPoints.length] = BuildingPoints;
    
    return B;
}

//timer checks for dead minions.
function Timer()
{
    local int i;
    for(i = 0; i < SummonedTurrets.length; i++)
    {
        if(SummonedTurrets[i] == None || SummonedTurrets[i].health <= 0)
        {
            UsedTurretPoints -= SummonedTurretPoints[i];
            if(UsedTurretPoints < 0)
            {
                Warn("Turret Points less than zero!");
                UsedTurretPoints = 0; //just an emergency checkertrap in case something interesting happens
            }
            SummonedTurrets.remove(i, 1);
            SummonedTurretPoints.remove(i, 1);
            i--;
        }
    }
    for(i = 0; i < SummonedVehicles.length; i++)
    {
        if(SummonedVehicles[i] == None || SummonedVehicles[i].health <= 0)
        {
            UsedVehiclePoints -= SummonedVehiclePoints[i];
            if(UsedVehiclePoints < 0)
            {
                Warn("Vehicle Points less than zero!");
                UsedVehiclePoints = 0; //just an emergency checkertrap in case something interesting happens
            }
            SummonedVehicles.remove(i, 1);
            SummonedVehiclePoints.remove(i, 1);
            i--;
        }
    }
    for(i = 0; i < SummonedBuildings.length; i++)
    {
        if(SummonedBuildings[i] == None || SummonedBuildings[i].health <= 0)
        {
            UsedBuildingPoints -= SummonedBuildingPoints[i];
            if(UsedBuildingPoints < 0)
            {
                Warn("Building Points less than zero!");
                UsedBuildingPoints = 0; //just an emergency checkertrap in case something interesting happens
            }
            SummonedBuildings.remove(i, 1);
            SummonedBuildingPoints.remove(i, 1);
            i--;
        }
    }
}

function rotator getSpawnRotator(Vector SpawnLocation)
{
    local rotator SpawnRotation;

    SpawnRotation.Yaw = rotator(SpawnLocation - Instigator.Location).Yaw;
    return SpawnRotation;
}

function KillAllTurrets()
{
    local int i;
    
    for(i = 0; i < 1000 && SummonedTurrets.length > 0; i++)
        KillFirstTurret();
}

function KillFirstTurret()
{
    if(SummonedTurrets.length == 0)
        return; //nothing to kill
    if(SummonedTurrets[0] != None)
    {
        if (Vehicle(SummonedTurrets[0]) != None && Vehicle(SummonedTurrets[0]).Driver != None)
            Vehicle(SummonedTurrets[0]).EjectDriver();
        SummonedTurrets[0].Health = 0;
        SummonedTurrets[0].LifeSpan = 0.1 * SummonedTurrets.length; //so the server will do it in it's own time and not all at once...
    }       
        
    UsedTurretPoints -= SummonedTurretPoints[0];
    if(UsedTurretPoints < 0)
    {
        Warn("Turret Points less than zero!");
        UsedTurretPoints = 0; //just an emergency checkertrap in case something interesting happens
    }
    SummonedTurrets.remove(0, 1);
    SummonedTurretPoints.remove(0, 1);
}

function KillAllVehicles()
{
    local int i;
    
    for(i = 0; i < 1000 && SummonedVehicles.length > 0; i++)
        KillFirstVehicle();
}

function KillFirstVehicle()
{
    if(SummonedVehicles.length == 0)
        return; //nothing to kill
    if(SummonedVehicles[0] != None)
    {
        if (Vehicle(SummonedVehicles[0]) != None && Vehicle(SummonedVehicles[0]).Driver != None)
            Vehicle(SummonedVehicles[0]).EjectDriver();
        SummonedVehicles[0].Health = 0;
        SummonedVehicles[0].LifeSpan = 0.1 * SummonedVehicles.length; //so the server will do it in it's own time and not all at once...
    }       
        
    UsedVehiclePoints -= SummonedVehiclePoints[0];
    if(UsedVehiclePoints < 0)
    {
        Warn("Vehicle Points less than zero!");
        UsedVehiclePoints = 0; //just an emergency checkertrap in case something interesting happens
    }
    SummonedVehicles.remove(0, 1);
    SummonedVehiclePoints.remove(0, 1);
}

function KillAllBuildings()
{
    local int i;
    
    for(i = 0; i < 1000 && SummonedBuildings.length > 0; i++)
        KillFirstBuilding();
}

function KillFirstBuilding()
{
    if(SummonedBuildings.length == 0)
        return; //nothing to kill
    if(SummonedBuildings[0] != None)
    {
        if (Vehicle(SummonedBuildings[0]) != None && Vehicle(SummonedBuildings[0]).Driver != None)
            Vehicle(SummonedBuildings[0]).EjectDriver();
        SummonedBuildings[0].Health = 0;
        SummonedBuildings[0].LifeSpan = 0.1 * SummonedBuildings.length; //so the server will do it in it's own time and not all at once...
    }       
        
    UsedBuildingPoints -= SummonedBuildingPoints[0];
    if(UsedBuildingPoints < 0)
    {
        Warn("Building Points less than zero!");
        UsedTurretPoints = 0; //just an emergency checkertrap in case something interesting happens
    }
    SummonedBuildings.remove(0, 1);
    SummonedBuildingPoints.remove(0, 1);
}

simulated function Destroyed()
{   
    if(Level.NetMode == NM_DedicatedServer || Level.NetMode == NM_ListenServer || Level.NetMode == NM_Standalone)
    {
        KillAllTurrets();
        KillAllVehicles();
        KillAllBuildings();
        setTimer(0, false);
    }
    if(Interaction != None)
    {
        Interaction.EInv = None; //clear the reference.
        RemoveInteraction();
    }
    
    super.Destroyed();
}

simulated function RemoveInteraction()
{
    if(Player != None && Player.InteractionMaster != None && Interaction != None)
        Player.InteractionMaster.RemoveInteraction(Interaction);
    if(Interaction != None)
        Interaction.Einv = None;
    Interaction = None;
}

static function string GetLocalString(optional int Switch, optional PlayerReplicationInfo RelatedPRI_1, optional PlayerReplicationInfo RelatedPRI_2)
{
    if (Switch == 1)
        return Default.NotEnoughAdrenalineMessage;
    if (Switch == 2)
        return Default.NotEnoughPointsMessage;
    if (Switch == 3)
        return Default.UnableToSpawnMessage;
    if (Switch == 4)
        return Default.TooManyToSpawnMessage;

    return Super.GetLocalString(Switch, RelatedPRI_1, RelatedPRI_2);
}

DefaultProperties
{
    RemoteRole=ROLE_SimulatedProxy
    NotEnoughAdrenalineMessage="You do not have enough adrenaline to summon this."
    NotEnoughPointsMessage="Insufficent points available to summon this."
    TooManyToSpawnMessage="You have summoned too many of these. You must kill one before you can summon another one."
    UnableToSpawnMessage="Unable to spawn."
    bOnlyRelevantToOwner=True
    MessageClass=Class'UnrealGame.StringMessagePlus'
    MaxTurrets=3
    MaxVehicles=2
    MaxBuildings=1
}