DruidsRPGcvs.DruidLinkSentinelController

class DruidLinkSentinelController extends LinkTurretController;

var Controller PlayerSpawner;
var float TimeSinceCheck;

function SetPlayerSpawner(Controller PlayerC)
{
    PlayerSpawner = PlayerC;
    if (PlayerSpawner.PlayerReplicationInfo != None && PlayerSpawner.PlayerReplicationInfo.Team != None )
    {
        if (PlayerReplicationInfo == None)
            PlayerReplicationInfo = spawn(class'PlayerReplicationInfo', self);
        PlayerReplicationInfo.PlayerName = PlayerSpawner.PlayerReplicationInfo.PlayerName$"'s Sentinel";
        PlayerReplicationInfo.bIsSpectator = true;
        PlayerReplicationInfo.bBot = true;
        PlayerReplicationInfo.Team = PlayerSpawner.PlayerReplicationInfo.Team;
        PlayerReplicationInfo.RemoteRole = ROLE_None;
    }
}

function Tick(float DeltaTime)
{
    // need to check for any monsters to target

    local Controller C;
    super.Tick(DeltaTime);

    TimeSinceCheck+=DeltaTime;
    
    if(TimeSinceCheck>0.5)
    {
        TimeSinceCheck-=0.5;
        for ( C = Level.ControllerList; C != None; C = C.NextController )
            if (!C.bIsPlayer && C.Pawn != None && FastTrace(C.Pawn.Location,Pawn.Location))
                SeePlayer(C.Pawn);
    }

}

State WaitForTarget
{
    function BeginState()
    {
        Target = Enemy;
        bFire = 1;
        if ( Pawn.Weapon != None )  
            Pawn.Weapon.BotFire(false);

        //hack for invasion monsters so they'll fight back
        if ( MonsterController(Enemy.Controller) != None && FriendlyMonsterController(Enemy.Controller) == None
              && Enemy.Controller.Enemy == PlayerSpawner.Pawn && FastTrace(Pawn.Location,Enemy.Location) && FRand() < 0.5 )
            MonsterController(Enemy.Controller).ChangeEnemy(Pawn, Enemy.Controller.CanSee(Pawn));

    }

Begin:
    Sleep( GetWaitForTargetTime() );
    GotoState('Searching'); 
}

function Destroyed()
{
    if (PlayerReplicationInfo != None)
        PlayerReplicationInfo.Destroy();

    Super.Destroyed();
}

defaultproperties
{
}